SUMMARY = "The Cockpit user interface for Podman containers."
DESCRIPTION = "This is the Cockpit user interface for podman containers."

LICENSE = "LGPL-2.1-only"
LIC_FILES_CHKSUM = "file://LICENSE;md5=4fbd65380cdd255951079008b364516c"

SRC_URI += "https://github.com/cockpit-project/cockpit-podman/releases/download/${PV}/cockpit-podman-${PV}.tar.xz \
           "

SRC_URI[sha256sum] = "a42d7dfabdd1a058c5b0f502bfd9380542d9666f047316ea1ff114e7b1db0877"

PR = "r3"

RDEPENDS:${PN} += "cockpit-bridge podman"

inherit allarch gettext

DEPENDS += "intltool-native virtual/gettext"

S = "${WORKDIR}/${BPN}"


FILES:${PN} += " \
    ${datadir}/cockpit/podman \
    ${datadir}/metainfo/org.cockpit-project.podman.metainfo.xml \
"

# Do configure call `make clean` by default, and cockpit-podman doesn't expect
# `make clean`to be called from the tarball release
do_configure() {
    :
}

# Do compile call `make` by default, and cockpit-podman doesn't expect
# `make`to be called from the tarball release
do_compile() {
    :
}

do_install() {
    cd ${B}
    oe_runmake -C ${S} install DESTDIR=${D}
}
