DESCRIPTION = "NetModule GNSS management tool"
LICENSE = "LGPL-3.0-only"
LIC_FILES_CHKSUM = "file://LICENSE;md5=3000208d539ec061b899bce1d9ce9404"

RDEPENDS:${PN} += " \
    python3-setuptools \
    nmubxlib \
    python3-systemd \
    "

DEPENDS = "python3-setuptools-git-version-native"

inherit setuptools3
inherit gitpkgv

inherit systemd
SYSTEMD_SERVICE:${PN} = "gnss-mgr.service"

inherit allarch

# Package Version (built from tags)
PKGV = "${GITPKGVTAG}"
# Recipe Version
PV = "1.0-git${SRCPV}"
PR = "r1"

SRC_URI = "git://gitlab.com/netmodule/tools/gnssmgr.git;protocol=ssh;user=git;branch=master"
SRCREV ?= "a3dad8288286ba10b6b753d896c9c79586ce2e90"
S = "${WORKDIR}/git"

PACKAGES =+ "${PN}-test"
SUMMARY:${PN}-test = "Addon to gnss-mgr for testing purposes"
FILES:${PN}-test = "${bindir}/gnss-config-reader"

do_install:append() {
    install -d ${D}${sysconfdir}/gnss
    install -m 0644 ${S}/config/gnss-neom8.conf ${D}${sysconfdir}/gnss/gnss0.conf

    install -d ${D}/${sbindir}/
    install -m 0755 ${S}/systemd/gnss-mgr-service.py ${D}${sbindir}/gnss-mgr-service

    install -d ${D}/${systemd_unitdir}/system/
    install -m 0644 ${S}/systemd/gnss-mgr.service ${D}/${systemd_unitdir}/system/

    # Test tool
    install -d ${D}${bindir}/
    install -m 0755 ${S}/testing/gnss-config-reader.py ${D}${bindir}/gnss-config-reader
}