# Copyright (C) 2018 NetModule AG

inherit kernel

DESCRIPTION = "Linux kernel for various NetModule hardware"

LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"

BRANCH_NAME = "${@'${MACHINE}'.split('-')[-1]}"
SRC_URI = "git://git.netmodule.intranet/yoctoproject/linux-netmodule.git;protocol=ssh;user=gitea;branch=4.14/standard/${BRANCH_NAME}"
SRCREV ?= "${AUTOREV}"
PV ?= "4.14.y-${SRCPV}"

PR = "r0"

S = "${WORKDIR}/git"

INSANE_SKIP_${PN} += "version-going-backwards"

#If a KERNEL_DEFCONFIG is specified, the defconfig specified in SRC_URI will be overwritten!
do_configure_append(){
    if [ "${KERNEL_DEFCONFIG}" != "" ]; then
        oe_runmake ${KERNEL_DEFCONFIG}
    fi
}

do_install_append(){
    if [ "${KERNEL_DEVICETREE}" != "" ]; then
        ln -s devicetree-${DTB_SYMLINK_NAME}.dtb ${D}/${KERNEL_IMAGEDEST}/devicetree.dtb
    fi
    if [ "${KERNEL_IMAGETYPE}" = "uImage" ]; then
        ln -s ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} ${D}/${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}
    fi

    # Module.symvers gets updated during the
    # building of the kernel modules. We need to
    # update this in the shared workdir since some
    # external kernel modules has a dependency on
    # other kernel modules and will look at this
    # file to do symbol lookups
    # THIS WILL BE FIXED IN FUTURE VERSIONS!
    cp Module.symvers ${STAGING_KERNEL_BUILDDIR}/
}

# NRHW18

do_install_append_armada-385-nrhw18() {
    ln -s devicetree-${DTB_SYMLINK_NAME}.dtb ${D}/${KERNEL_IMAGEDEST}/armada-385-nbhw18-prod4.dtb
}

# MEK 

do_configure_prepend_imx8-mek() {
    install -d ${B}
    mkdir -p ${B}
    cp ${S}/arch/arm64/configs/defconfig ${B}/.config
    echo "CONFIG_BLK_DEV_RAM=y" >> ${B}/.config
    echo "CONFIG_BLK_DEV_RAM_COUNT=1" >> ${B}/.config
    echo "CONFIG_BLK_DEV_RAM_SIZE=131072" >> ${B}/.config
    echo "CONFIG_BLK_DEV_RAM_BLOCKSIZE=1024" >> ${B}/.config
    echo "CONFIG_INITRAMFS_COMPRESSION_GZIP=y" >> ${B}/.config
}
EXTRA_OEMAKE_append_imx8-mek = " ARCH=arm64"
KERNEL_EXTRA_ARGS_append_imx8-mek += "LOADADDR=${UBOOT_ENTRYPOINT}"