# Copyright (C) 2018 NetModule AG

inherit kernel

DESCRIPTION = "Linux kernel for various NetModule hardware"

LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=bbea815ee2795b2f4230826c0c6b8814"

SRC_URI = "git://git.netmodule.intranet/yoctoproject/linux-netmodule.git;protocol=ssh;user=gitea;branch=4.19/standard/base"

# Config fragments
FILESEXTRAPATHS_prepend := "${THISDIR}/conf:"
SRC_URI_append_netbird = " file://wlan.cfg"

SRCREV ?= "${AUTOREV}"
PV ?= "4.19.88-${SRCPV}"

SRC_URI_imx8-nmhw23 = "git://git.netmodule.intranet/yoctoproject/linux-netmodule.git;protocol=ssh;user=gitea;branch=4.14/nxp/nmhw23"
SRCREV_imx8-nmhw23 ?= "${AUTOREV}"
PV_imx8-nmhw23 ?= "4.14.98-${SRCPV}"
LIC_FILES_CHKSUM_imx8-nmhw23 = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"

PR = "r0"

S = "${WORKDIR}/git"

INSANE_SKIP_${PN} += "version-going-backwards"

#If a KERNEL_DEFCONFIG is specified, the defconfig specified in SRC_URI will be overwritten!
do_configure_append(){
    if [ "${KERNEL_DEFCONFIG}" != "" ]; then
        oe_runmake ${KERNEL_DEFCONFIG}
    fi

    configs="${@" ".join(find_cfgs(d))}"
    if [ ! -z "${configs}" ]; then
        ${S}/scripts/kconfig/merge_config.sh -m -O ${WORKDIR}/build ${WORKDIR}/build/.config ${WORKDIR}/*.cfg
    fi
}

do_install_append(){
    if [ "${KERNEL_DEVICETREE}" != "" ]; then
        ln -s ${KERNEL_DTB_LINK_NAME}.dtb ${D}/${KERNEL_IMAGEDEST}/devicetree.dtb
    fi
    if [ "${KERNEL_IMAGETYPE}" = "uImage" ]; then
        ln -s ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} ${D}/${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}
    fi

    # Module.symvers gets updated during the
    # building of the kernel modules. We need to
    # update this in the shared workdir since some
    # external kernel modules has a dependency on
    # other kernel modules and will look at this
    # file to do symbol lookups
    # THIS WILL BE FIXED IN FUTURE VERSIONS!
    cp Module.symvers ${STAGING_KERNEL_BUILDDIR}/
}

# NRHW18

do_install_append_armada-385-nrhw18() {
    ln -s ${KERNEL_DTB_LINK_NAME}.dtb ${D}/${KERNEL_IMAGEDEST}/armada-385-nbhw18-prod4.dtb
}

do_install_append_am335x-nrhw16() {
    ln -s am335x-nrhw16.dtb ${D}/${KERNEL_IMAGEDEST}/am335x-nbhw16.dtb
    ln -s am335x-nrhw16-prod2.dtb ${D}/${KERNEL_IMAGEDEST}/am335x-nbhw16-prod2.dtb
    ln -s am335x-nrhw16-prod3.dtb ${D}/${KERNEL_IMAGEDEST}/am335x-nbhw16-prod3.dtb
    ln -s am335x-nrhw16-prod4.dtb ${D}/${KERNEL_IMAGEDEST}/am335x-nbhw16-prod4.dtb
    ln -s am335x-nrhw16-prod5.dtb ${D}/${KERNEL_IMAGEDEST}/am335x-nbhw16-prod5.dtb
}
# NMHW23

do_configure_prepend_imx8-nmhw23() {
    install -d ${B}
    mkdir -p ${B}
    cp ${S}/arch/arm64/configs/defconfig ${B}/.config
    echo "CONFIG_BLK_DEV_RAM=y" >> ${B}/.config
    echo "CONFIG_BLK_DEV_RAM_COUNT=1" >> ${B}/.config
    echo "CONFIG_BLK_DEV_RAM_SIZE=131072" >> ${B}/.config
    echo "CONFIG_BLK_DEV_RAM_BLOCKSIZE=1024" >> ${B}/.config
    echo "CONFIG_INITRAMFS_COMPRESSION_GZIP=y" >> ${B}/.config
}
EXTRA_OEMAKE_append_imx8-nmhw23 = " ARCH=arm64"
KERNEL_EXTRA_ARGS_append_imx8-nmhw23 += "LOADADDR=${UBOOT_ENTRYPOINT}"

#Apply config fragments
def find_cfgs(d):
    sources=src_patches(d, True)
    sources_list=[]
    for s in sources:
        if s.endswith('.cfg'):
            sources_list.append(s)
    return sources_list