# Global
TARGET_VENDOR = "-netmodule"
SANITY_TESTED_DISTROS ?= " \
            debian-10 \n \
            debian-11 \n \
            debian-12 \n \
            "

# Make shared states compatible with all build host
require conf/distro/include/yocto-uninative.inc
INHERIT += "uninative"
# Don't append libc name in tmp directory
# eg. build/tmp instead of build/tmp-glibc
# Since we only support glibc, we don't need different tmp directories
TCLIBCAPPEND = ""


# DISTRO
DISTRO = "netmodule-linux"
DISTRO_NAME = "NetModule Linux Distribution"
DISTRO_VERSION ?= "x.y.z.develop"

INIT_MANAGER = "systemd"
KERNEL_MODULE_AUTOLOAD += "cryptodev"

DISTRO_FEATURES = "bluetooth usbhost pci ipv4 ipv6 wifi multiarch usrmerge"

# The BACKFILLed features are features which were defaults in previous
# yocto versions but are now optional.
# Adding them to this variable allow us to remove them.
DISTRO_FEATURES_BACKFILL_CONSIDERED = "pulseaudio gobject-introspection-data ldconfig"

EXTRA_IMAGECMD_append_ext4 = " -O ^64bit"
EXTRA_IMAGECMD_append_ota-ext4 = " -O ^64bit"


# Packages
PACKAGECONFIG_append_pn-curl = " tftp ssl"
PACKAGECONFIG_remove_pn-curl = "gnutls"

PACKAGECONFIG_append_pn-libgpiod = " python3"
PACKAGECONFIG_append_pn-networkmanager = " modemmanager"
PACKAGECONFIG_pn-gpsd = ""
PACKAGECONFIG_append_pn-openssl = " cryptodev-linux"
PACKAGECONFIG_pn-lmsensors = ""
PACKAGECONFIG_pn-libqmi = ""

# These rules may make gpsd start automatically when detecting a
# receiver. We don't want that since gpsd is started by gnss-mgr
PACKAGE_EXCLUDE = "gpsd-udev"


# SDK
SDK_NAME = "${DISTRO}-${TCLIBC}-${SDK_ARCH}-${IMAGE_BASENAME}-${TUNE_PKGARCH}"
SDKPATH = "/opt/${DISTRO}/${SDK_VERSION}"
SDK_VENDOR = "-netmodule"
SDK_VERSION := "${@'${DISTRO_VERSION}'.replace('snapshot-${DATE}','snapshot')}"