inherit core-image

SUMMARY = "NetModule Linux Distro Image"

KERNEL_IMAGETYPE = "uImage"

IMAGE_FEATURES_append = " \
                package-management \
                ssh-server-openssh \
                "

FIRMWARE ?= "linux-firmware"

FIRMWARE_am335x-nrhw20 = " \
	        linux-firmware-ath6k \
                linux-firmware-ath9k \
                linux-firmware-wl12xx\
                linux-firmware-wl18xx\
                wlconf-bin \
                "

FIRMWARE_am335x-nmhw21 = " \
                linux-firmware-wl18xx\
                wlconf-bin \
                "


FIRMWARE_am335x-nrhw16 = " \
                linux-firmware-ath6k \
                linux-firmware-ath9k \
                linux-firmware-wl12xx\
                linux-firmware-wl18xx\
                wlconf-bin \
                "
FIRMWARE_armada-385 = " \
                linux-firmware-ath6k \
                linux-firmware-ath9k \
                "

IMAGE_INSTALL_append = " \
                hostapd \
                iw \
                crda \
                wpa-supplicant \
                openssh-sftp-server \
                bash \
                iproute2 \
                ethtool \
                openvpn \
                iptables \
                pciutils \
                kernel-modules \
                kernel-devicetree \
                networkmanager \
                modemmanager \
                parted \
                rng-tools \
                glibc-utils \
                glibc-gconv \
                glibc-gconv-utf-16 \
                glibc-gconv-utf-32 \
                bridge-utils \
                gpsd \
                curl \
                less \
                nmhw-auto-part \
                ${FIRMWARE} \
                "

IMAGE_INSTALL_cortex9hf-neon_append = " kernel-devicetree "
IMAGE_INSTALL_cortex9hf_append = " kernel-devicetree "
IMAGE_INSTALL_append_am335x-nrhw16 = " \
                tibluetooth \
                bluez5-obex \
                bluez5-noinst-tools \
                canutils \
                wakeup-timer \
                "

IMAGE_INSTALL_append_armada-385-nrhw18 = " \
                fpga-image \
                "

IMAGE_INSTALL_append_am335x-nrhw20 = " \
                tibluetooth \
                bluez5-obex \
                bluez5-noinst-tools \
                "

IMAGE_INSTALL_append_am335x-nmhw21 = " \
                tibluetooth \
                bluez5-obex \
                bluez5-noinst-tools \
                can-utils \
                spitools \
                socat \
                libgpiod \
                battery-test \
                cryptodev-module \
                socket-uart \
                ublox-configuration \
                modem-config-dump \
                mac-address-set \
                sim-config \
                "

FPGA_INSTALL = " \
    nm-scripts-fpga \
    "

IMAGE_INSTALL_append_armada-385-nbhw14 = " ${FPGA_INSTALL}"
IMAGE_INSTALL_append_armada-385-nbhw17 = " ${FPGA_INSTALL}"

LICENSE = "BSD"

KERNEL_IMAGETYPE_sota = "fitImage"
IMAGE_OVERHEAD_FACTOR = "1.0"
OSTREE_BOOTLOADER = "u-boot"
OSTREE_BRANCHNAME ?= "${MACHINE}"

IMAGE_PREPROCESS_COMMAND_sota += " moveRPMDatabase;"

BUILDNAME = "${EXTERNALSRC_GIT_SRCREV};${DATETIME};${PN}"

# Change the location of /var/lib/rpm to /usr/lib/rpm.
# This makes the rpm package index consistent with installed packages.
moveRPMDatabase() {
 cd ${WORKDIR}/rootfs
 mv var/lib/rpm/* usr/lib/rpm
 rm -r var/lib/rpm
 echo "L /var/lib/rpm - - - - /usr/lib/rpm" > etc/tmpfiles.d/ostree-rpm.conf
}